mirror of
https://github.com/ItsDrike/dotfiles.git
synced 2024-12-30 22:44:35 +00:00
75 lines
2.4 KiB
Bash
Executable file
75 lines
2.4 KiB
Bash
Executable file
#!/usr/bin/env zsh
|
|
# Set default keybindings (mostly from oh-my-zsh)
|
|
|
|
# Make sure that the terminal is in application mode when zle is active, since
|
|
# only then values from $terminfo are valid
|
|
if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
|
|
function zle-line-init() {
|
|
echoti smkx
|
|
}
|
|
function zle-line-finish() {
|
|
echoti rmkx
|
|
}
|
|
zle -N zle-line-init
|
|
zle -N zle-line-finish
|
|
fi
|
|
|
|
# Use vim keybindings
|
|
bindkey -v
|
|
|
|
# [PageUp] - Up a line of history
|
|
[[ -n "${terminfo[kpp]}" ]] && bindkey "${terminfo[kpp]}" up-line-or-history
|
|
# [PageDown] - Down a line of history
|
|
[[ -n "${terminfo[knp]}" ]] && bindkey "${terminfo[knp]}" down-line-or-history
|
|
|
|
# Start typing + [Up-Arrow] - fuzzy find history forward
|
|
if [[ -n "${terminfo[kcuu1]}" ]]; then
|
|
autoload -U up-line-or-beginning-search
|
|
zle -N up-line-or-beginning-search
|
|
bindkey "${terminfo[kcuu1]}" up-line-or-beginning-search
|
|
fi
|
|
# Start typing + [Down-Arrow] - fuzzy find history backward
|
|
if [[ -n "${terminfo[kcud1]}" ]]; then
|
|
autoload -U down-line-or-beginning-search
|
|
zle -N down-line-or-beginning-search
|
|
bindkey "${terminfo[kcud1]}" down-line-or-beginning-search
|
|
fi
|
|
|
|
# [Home] - Go to beginning of line
|
|
[[ -n "${terminfo[khome]}" ]] && bindkey "${terminfo[khome]}" beginning-of-line
|
|
# [End] - Go to end of line
|
|
[[ -n "${terminfo[kend]}" ]] && bindkey "${terminfo[kend]}" end-of-line
|
|
|
|
# [Shift-Tab] - move through the completion menu backwards
|
|
[[ -n "${terminfo[kcbt]}" ]] && bindkey "${terminfo[kcbt]}" reverse-menu-complete
|
|
|
|
# [Backspace] - delete backward
|
|
bindkey '^?' backward-delete-char
|
|
# [Delete] - delete forward
|
|
if [[ -n "${terminfo[kdch1]}" ]]; then
|
|
bindkey "${terminfo[kdch1]}" delete-char
|
|
else
|
|
bindkey "^[[3~" delete-char
|
|
bindkey "^[3;5~" delete-char
|
|
fi
|
|
|
|
# [Ctrl-Delete] - delete whole forward-word
|
|
bindkey '^[[3;5~' kill-word
|
|
|
|
# [Ctrl-RightArrow] - move forward one word
|
|
bindkey '^[[1;5C' forward-word
|
|
# [Ctrl-LeftArrow] - move backward one word
|
|
bindkey '^[[1;5D' backward-word
|
|
|
|
bindkey '^r' history-incremental-search-backward # [Ctrl-r] - Search backward incrementally for a specified string. The string may begin with ^ to anchor the search to the beginning of the line.
|
|
bindkey ' ' magic-space # [Space] - don't do history expansion
|
|
|
|
# Edit the current command line in $EDITOR
|
|
autoload -U edit-command-line
|
|
zle -N edit-command-line
|
|
bindkey '\C-x\C-e' edit-command-line
|
|
|
|
|
|
# [ctrl+space] Accept suggestion from zsh-autosuggestions plugin
|
|
bindkey '^ ' autosuggest-accept
|