import QtQuick
import Solitare

Row {
    id: foundationRow

    required property real cardWidth
    required property real cardHeight

    spacing: cardWidth * 0.2

    Repeater {
        model: 4 // Each of the 4 suits

        Item {
            id: foundationPile
            width: foundationRow.cardWidth
            height: foundationRow.cardHeight

            required property int index // passed from repeater

            CardModel {
                id: foundationCard

                anchors.fill: parent
                visible: GameState.foundation[parent.index].length > 0

                card: GameState.foundation[parent.index].length > 0 ? GameState.foundation[parent.index][0] : null
                isFaceDown: false
            }

            Rectangle {
                id: emptyPileRect

                anchors.fill: parent
                visible: GameState.foundation[parent.index].length === 0

                color: "gray"
                border.color: "white"
                border.width: width * 0.03
                opacity: 0.4
                radius: width * 0.125

                Text {
                    text: "A"
                    color: "white"
                    font.pixelSize: parent.width * 0.5
                    font.bold: true

                    anchors.centerIn: parent
                }
            }
        }
    }
}